Softdisk Supreme/Softdisk Supreme.iso/pc/DSK Files/0-49/SD003b.dsk/FAST.FORWARD.MUSIC.bas

BASIC Source File | 2003-06-12 | 12KB | 353 lines

0  REM    FAST-> FORWARD-> MUSIC
1  ONERR  GOTO 8000
2  GOSUB 9000
3 T =  PEEK(78):D =  RND( -1): FOR A = 1 TO T +2:D =  RND(1): NEXT
4  REM RANDOMIZE BY T.CRAWFORD,
5  REM CALL -APPLE FEB.'81
6  GOTO 20000
20  GOTO 10000
22  REM
23  REM
24  REM    +------------------+
25  REM    I   CHOOSE RANDOM  I
26  REM    I       NOTES      I
27  REM    +------------------+
28  REM
29  REM
35  FOR S1 = 1 TO 10
40 CLEF =  INT(2 * RND(1)) +1
45  GOSUB 1000
50 Z =  INT(12 * RND(1)) +1
55  IF T5  THEN Z = 11
60 T = 1
65  FOR X = 9 TO 35  STEP 5
66  IF T5  THEN Z = Z -1: GOTO 100
70 D =  INT(2 * RND(1))
75  IF D  THEN Z = Z +1: GOTO 90
80 Z = Z -1
90 Z = Z -(Z -1) *(Z <1)
100 Z = Z -(Z -12) *(Z >12)
110  IF  RND(1) >DF *.01  THEN Z =  INT(12 * RND(1)) +1
120  IF CLEF = 2  AND X = 9  AND Z <7  THEN Z = 7
130 NTE(T) = Z
140 Y1(T) = 5 *(Z = 1) +8 *(Z = 2) +10 *(Z = 3) +13 *(Z = 4) +15 *(Z = 5) +18 *(Z = 6) +20 *(Z = 7) +23 *(Z = 8) +25 *(Z = 9) +28 *(Z = 10) +30 *(Z = 11) +33 *(Z = 12) +35 *(Z = 13)
150 Y = Y1(T)
280  REM SET-UP NOTES
283  ON CLEF GOSUB 500,550
284 T = T +1
289  GOSUB 2000: NEXT X
290  ON CLEF GOSUB 6000,6190
300  IF T5  THEN 20290
320  GOSUB 4000
330  NEXT S1
340  GOTO 80
500  REM TREBLE
510  ON Z GOSUB 6070,6080,6090,6100,6110,6120,6130,6140,6150,6160,6170,6180
520  RETURN
550  REM BASS
560  ON Z GOSUB 6260,6270,6280,6290,6300,6310,6320,6330,6340,6350,6360,6370
570  RETURN
991  REM
992  REM
993  REM     +-----------------+
994  REM     I   DRAW  STAFF   I
995  REM     +-----------------+
996  REM
997  REM
1000  IF   NOT T5  THEN  HOME
1010  IF  SCRN( 4,8) = 15  THEN 1030
1020  GR
1030 D =  INT(9 * RND(1))
1035  IF D < >1  AND D < >2  AND D < >4  AND D < >8  OR D =  SCRN( 0,0)  THEN 1030
1040  COLOR= D
1050  ON CLEF GOTO 1060,1080
1060  FOR X = 0 TO 19: VLIN 0,39 AT X: VLIN 0,39 AT 39 -X: NEXT
1070  GOTO 1090
1080  FOR Y = 0 TO 19: HLIN 0,39 AT Y: HLIN 0,39 AT 39 -Y: NEXT
1090  COLOR= 11: ON CLEF GOTO 1100,1120
1100  FOR Y = 9 TO 18: HLIN 1,38 AT Y: HLIN 1,38 AT 37 -Y: NEXT
1110  GOTO 1130
1120  FOR X = 1 TO 19: VLIN 9,27 AT X: VLIN 9,27 AT 39 -X: NEXT
1130  COLOR= 6
1140  FOR Y = 8 TO 28  STEP 5
1150  HLIN 1,38 AT Y
1160  NEXT Y
1170  VLIN 8,28 AT 0: VLIN 8,28 AT 39
1180  COLOR= 15
1190  ON CLEF GOSUB 1210,1250
1200  RETURN
1210  REM TREBLE CLEF
1220  VLIN 4,30 AT 4: PLOT 3,30: PLOT 5,6: VLIN 7,9 AT 6: VLIN 10,11 AT 5: VLIN 13,14 AT 3: VLIN 14,15 AT 2: VLIN 16,18 AT 1: VLIN 18,23 AT 0: VLIN 23,24 AT 1: VLIN 24,25 AT 2: VLIN 25,27 AT 3: VLIN 25,27 AT 5
1230  VLIN 24,25 AT 6: VLIN 21,24 AT 7: VLIN 19,20 AT 6: HLIN 3,5 AT 18: VLIN 19,20 AT 2
1240 TP = TP +6: RETURN
1250  REM BASS CLEF
1260  HLIN 3,5 AT 8: VLIN 9,10 AT 2: VLIN 10,14 AT 1: VLIN 14,15 AT 2: VLIN 15,16 AT 3
1270  VLIN 9,10 AT 6: VLIN 11,17 AT 7: VLIN 17,18 AT 6: VLIN 19,20 AT 5: VLIN 21,22 AT 4
1280  VLIN 21,22 AT 3: VLIN 10,11 AT 9: VLIN 15,16 AT 9: PLOT 2,23
1290 BP = BP +6: RETURN
1991  REM
1992  REM
1993  REM   +------------------+
1994  REM   I  DRAW A NOTE AT  I
1995  REM   I       (X,Y)      I
1996  REM   +------------------+
1997  REM
2000  COLOR= 12
2010  IF Y >30  THEN  GOSUB 2130
2030  IF FLAG  THEN  COLOR= 0
2040  HLIN X +1,X +2 AT Y -1
2050  HLIN X,X +3 AT Y
2060  HLIN X,X +3 AT Y +1
2070  HLIN X +1,X +2 AT Y +2
2080  IF Y <9  THEN 2110
2090  VLIN Y -10,Y AT X +3
2100  RETURN
2110  VLIN Y,Y +10 AT X: RETURN
2120  REM LEGER LINE
2130  COLOR= 6
2140  HLIN X -1,X +4 AT Y
2150  COLOR= 12: RETURN
3991  REM
3992  REM
3993  REM    +-----------------+
3994  REM    I IDENTIFY  NOTES I
3995  REM    +-----------------+
3996  REM
4000  REM
4010 A = 0
4020  FOR X = 9 TO 35  STEP 5
4030  HOME
4040 PD = 0
4060 A = A +1
4080  FOR T = 1 TO DF
4085 FL = (T/2 =  INT(T/2))
4090  IF FLAG  THEN 4100
4095 FLAG = 0
4100 Y = Y1(A)
4110  GOSUB 2000
4120  GOSUB 4500
4125  IF  PEEK( -16287) >127  THEN FLAG = 1:T = DF: NEXT T: GOSUB 2000: GOTO 4140
4130  FOR D = 1 TO DF: NEXT D,T
4135  GOTO 4260
4140  VTAB 23: HTAB 21:ANS$ = P$
4160 T = 0
4170 N = NTE(A):FLAG = 1
4175 PI = PI(A): IF ANS$ < >NTE$(A)  THEN 4195
4177  ON CLEF GOSUB 6040,6230
4180 TS = TS +((ANS$ = NTE$(A)) *(CLEF = 1))
4190 BS = BS +((ANS$ = NTE$(A)) *(CLEF = 2))
4193  GOSUB 7000: GOTO 4230
4195  HOME
4200  PRINT "SORRY "NAME$", BUT YOU'RE WRONG..."
4202  IF DF = 10  THEN 4208
4204  PRINT "THE CORRECT ANSWER WAS ";: FLASH : PRINT NTE$(A);: NORMAL : PRINT ".";
4206  GOTO 4210
4208  PRINT : FLASH : HTAB 9: PRINT " BETTER LUCK NEXT TIME! ": NORMAL
4210  GOSUB 5000
4220  FOR D = 1 TO 1500: NEXT
4230 FLAG = 0: GOSUB 2000: NEXT
4240  ON CLEF GOSUB 6000,6190
4245 DF = DF -5
4247 DF = DF +5 *(DF = 5)
4250  RETURN
4260 PI = PI(A)
4265  HOME : PRINT "OH, "NAME$" - YOUR TIME IS UP!"
4275  IF DF = 10  THEN 4290
4280  PRINT : PRINT "THIS NOTE IS ";: FLASH : PRINT NTE$(A);: NORMAL : PRINT ".";
4290  GOSUB 5000: GOTO 4220
4500 TI = 1 + INT( PDL(0)/36.4):TI = TI -(TI -7) *(TI >7): IF PD = TI  THEN  RETURN
4505  INVERSE : VTAB 21: PRINT "             A B C D E F G              ": NORMAL
4510 PD = TI
4515 P$ =  CHR$(64 +PD)
4517 HT = 12 +2 *PD
4520  VTAB 21: HTAB HT: PRINT P$: RETURN
4991  REM
4992  REM
4993  REM      +----------+
4994  REM      I BUZZER!! I
4995  REM      +----------+
5000  REM
5010  FOR D = 1 TO 25
5020  POKE 768,PI: POKE 769,8
5025  CALL 770: NEXT
5030  RETURN
5991  REM
5992  REM
5993  REM    +---------------+
5994  REM    I  PLAY  NOTES  I
5995  REM    +---------------+
5996  REM
5997  REM
6000  REM PLAY IN TREBLE CLEF
6010 T = 0: FOR X = 9 TO 35  STEP 5:T = T +1
6020 PI = PI(T):Y = Y1(T)
6025  COLOR= 0: GOSUB 2040
6040  POKE 768,PI: POKE 769,DF *2
6050  CALL 770
6052  GOSUB 2000
6055  IF FLAG  THEN  RETURN
6060  NEXT : RETURN
6070 PI(T) = 85:NTE$(T) = "G": RETURN
6080 PI(T) = 96:NTE$(T) = "F": RETURN
6090 PI(T) = 102:NTE$(T) = "E": RETURN
6100 PI(T) = 114:NTE$(T) = "D": RETURN
6110 PI(T) = 128:NTE$(T) = "C": RETURN
6120 PI(T) = 136:NTE$(T) = "B": RETURN
6130 PI(T) = 152:NTE$(T) = "A": RETURN
6140 PI(T) = 171:NTE$(T) = "G": RETURN
6150 PI(T) = 192:NTE$(T) = "F": RETURN
6160 PI(T) = 203:NTE$(T) = "E": RETURN
6170 PI(T) = 228:NTE$(T) = "D": RETURN
6180 PI(T) = 0:NTE$(T) = "C": RETURN
6190  REM PLAY NOTES (BASS)
6200 T = 0: FOR X = 9 TO 35  STEP 5:T = T +1
6210 PI = PI(T):Y = Y1(T)
6215  COLOR= 0: GOSUB 2040
6230  POKE 768,PI: POKE 769,DF *2
6240  CALL 770
6243  GOSUB 2000
6245  IF FLAG  THEN  RETURN
6250  NEXT : RETURN
6260 PI(T) = 68:NTE$(T) = "B": RETURN
6270 PI(T) = 76:NTE$(T) = "A": RETURN
6280 PI(T) = 85:NTE$(T) = "G": RETURN
6290 PI(T) = 96:NTE$(T) = "F": RETURN
6300 PI(T) = 102:NTE$(T) = "E": RETURN
6310 PI(T) = 114:NTE$(T) = "D": RETURN
6320 PI(T) = 128:NTE$(T) = "C": RETURN
6330 PI(T) = 136:NTE$(T) = "B": RETURN
6340 PI(T) = 152:NTE$(T) = "A": RETURN
6350 PI(T) = 171:NTE$(T) = "G": RETURN
6360 PI(T) = 192:NTE$(T) = "F": RETURN
6370 PI(T) = 203:NTE$(T) = "E": RETURN
6991  REM
6992  REM
6993  REM   +-----------------+
6994  REM   I CORRECT  ANSWER I
6995  REM   I      GIVEN!     I
6996  REM   +-----------------+
6997  REM
6998  REM
7000  REM
7005  INVERSE : VTAB 24: HTAB 16: PRINT " CORRECT! ";: NORMAL
7010  FOR T = 1 TO 10: POKE 768,255: POKE 769,10: CALL 770: NEXT : RETURN
7991  REM
7992  REM
7993  REM   +------------------+
7994  REM   I FINAL EVALUATION I
7995  REM   +------------------+
7996  REM
8000  REM
8010  TEXT : HOME : VTAB 5
8015  FOR TI = 0 TO 3
8020  FOR T = 255 TO 75  STEP  -10: POKE 768,T: POKE 769,9: CALL 770: NEXT : NEXT
8025  IF   NOT TP  AND   NOT BP  THEN 8080
8030  PRINT "EVALUATION: "NAME$
8040  PRINT : PRINT "FINAL DIFFICULTY LEVEL: "; INT(DF/10)
8045  IF   NOT BP  THEN 8055
8050  PRINT : PRINT "BASS: "BS" OUT OF "BP", OR " INT(BS/BP *100)"%"
8055  IF   NOT TP  THEN 8070
8060  PRINT : PRINT "TREBLE: "TS" OUT OF "TP", OR " INT(TS/TP *100)"%"
8070  PRINT : PRINT "TOTAL SCORE: "BS +TS" OUT OF "BP +TP", OR " INT((BS +TS)/(BP +TP) *100)"%"
8080  VTAB 20: POKE  -16368,0
8090  INPUT "CARE TO TRY AGAIN? ";ANS$
8100 ANS$ =  LEFT$(ANS$,1)
8110  IF ANS$ = "Y"  THEN  RUN 10180
8120  IF ANS$ < >"N"  THEN 8090
8125  PRINT
8130  PRINT "BYE "NAME$"!": END
8991  REM
8992  REM
8993  REM  +-------------------+
8994  REM  I POKE TONE ROUTINE I
8995  REM  +-------------------+
8996  REM
8997  REM
9000  REM
9010  FOR T = 770 TO 790
9020  READ A: POKE T,A
9030  NEXT : RETURN
9100  DATA 173,48,192,136,208,5,206,1,3,240,9,202,208,245,174,0,3,76,2,3,96
9990  REM
9991  REM
9992  REM
9993  REM     +----------------+
9994  REM     I  INSTRUCTIONS  I
9995  REM     +----------------+
9996  REM
9997  REM
9998  REM
10000  TEXT : HOME : HTAB 10
10010  PRINT "FAST-> FORWARD-> MUSIC"
10020  PRINT : PRINT
10030  PRINT "   THIS PROGRAM IS A COLOR/SOUND QUIZ ON"
10040  PRINT "SIMPLE MUSICAL NOTATION & ON THE IDENTI-"
10050  PRINT "FICATION OF NOTES IN THE BASS AND TREBLE"
10060  PRINT "CLEFS.  LEGER LINES WILL BE INCORPORATED"
10065  PRINT "AS WILL A TIME LIMIT BASED ON DIFFICULTY"
10070  PRINT "LEVEL.  PLEASE NOTE THAT THE GAME PADDLE"
10075  PRINT "SET OR JOYSTICK MUST BE CONNECTED BEFORE"
10080  PRINT "RUNNING THIS PROGRAM..."
10085  VTAB 20: INPUT "DO YOU WISH FURTHER INSTRUCTIONS? ";ANS$
10087 ANS$ =  LEFT$(ANS$,1): IF ANS$ < >"Y"  AND ANS$ < >"N"  THEN 10000
10090  IF ANS$ = "N"  THEN 10180
10095  HOME : VTAB 5: HTAB 11: PRINT "-=* INSTRUCTIONS *=-"
10100  PRINT : PRINT "    AFTER ENTERING YOUR DESIRED STARTING"
10105  PRINT "DIFFICULTY LEVEL,  YOU WILL BE PRESENTED"
10110  PRINT "WITH A SET OF 10 SCALES OF 6 NOTES EACH."
10115  PRINT "THE MOTIF WILL BE PLAYED FOLLOWING WHICH"
10120  PRINT "EACH OF THE NOTES WILL FLASH UNTIL *YOU*"
10125  PRINT "IDENTIFY THEM.  A TIME LIMIT WILL BE IM-"
10127  PRINT "POSED & WILL SHORTEN  WITH EACH SUCCESS-"
10130  PRINT "IVE SCALE OF NOTES."
10132  VTAB 24: HTAB 7: PRINT "PRESS <SPACE BAR> TO CONTINUE";
10133  POKE  -16368,0: WAIT  -16384,128: POKE  -16368,0: HOME
10135  VTAB 7: PRINT "    TO IDENTIFY A NOTE, TURN GAME PADDLE"
10137  PRINT "#0 SO THE CURSOR BLOCK APPEARS  OVER THE"
10140  PRINT "DESIRED NOTE. PRESS THE PADDLE BUTTON TO"
10142  PRINT "ENTER THE NOTE AS YOUR ANSWER."
10144  PRINT : PRINT : GOTO 10190
10180  HOME : VTAB 10
10190  INPUT "PLEASE ENTER YOUR FIRST NAME:";NAME$
10205  IF NAME$ = ""  THEN 10195
10210  PRINT
10220  FOR T = 1 TO  LEN(NAME$)
10230  IF  ASC( MID$ (NAME$,T,1)) = 32  THEN NAME$ =  LEFT$(NAME$,T -1): GOTO 10250
10240  NEXT
10250  PRINT "HI THERE "NAME$","
10260  PRINT : PRINT "WELCOME TO MUSICAL NOTATION!!"
10262  PRINT : PRINT "WHICH DIFFICULTY LEVEL WOULD YOU LIKE TO": PRINT "START AT? (1-10,1=HARDEST) ";: INPUT DF
10264  IF DF <1  OR DF >10  THEN  PRINT : PRINT "PLEASE TYPE A NUMBER FROM 1 TO 10:": PRINT : GOTO 10262
10266 DF = DF *10
10290  GOSUB 9000: GOTO 35
15002  REM
15003  REM
15004  REM   +--------------+
15005  REM   I  TITLE PAGE  I
15006  REM   +--------------+
15007  REM
15008  REM
20000  GR
20010  HOME
20240  VTAB 22
20245  INVERSE : HTAB 9: PRINT " FAST-> FORWARD-> MUSIC "
20260  HTAB 9: PRINT "       BY JIM GANZ      "
20285 T5 = 1:CLEF = 1:DF = 100: FOR S1 = 1 TO 10: GOTO 45
20290  HTAB 9: PRINT " PRESS ANY KEY TO BEGIN ";: NORMAL
20295  POKE  -16368,0: WAIT  -16384,128: POKE  -16368,0
20300  RUN 20
50000  REM
50001  REM
50002  REM
50003  REM +------------------+
50004  REM FAST->FORWARD->MUSIC
50006  REM :   BY JIM GANZ    :
50007  REM :  82 SPRING LANE  :
50008  REM : WEST HARTFORD,CT :
50009  REM :       06107      :
50010  REM :     17-MAY-81    :
50011  REM +------------------+
50012  REM
50013  REM
50014  REM             /
50015  REM         EL FIN